*This program creates the ESR and its collapsing status variable.
*
/*	ESR variable: Employment Status Recode (ESR): youth's employment status during the week before the survey
(from CPS section): (CV_ESR or R1200800)

1. at work
2. with job, not at work
3. layoff, unemployed
4. look for work, unemployed
5. not in labor force, retired
6. not in labor force, disabled (long-term physical or mental illness, lasting six months or longer)
7. not in labor force, other
8. in Active Armed Forces
Note: The Active Armed Forces category should be listed before an employee-type job.


	Collapsed ESR code: (CV_ESR_COLLAPSED or R1200900)

1. employed
2. unemployed
3. not in the labor force
4. in Active Armed Forces   	*/


/*	It uses the following variables:

  C2100     = "CHK R 15+ ON INT DATE (CPS) 1997"	      ---YCPS-2100
  C2300     = "CHK R 17 OR OLDER ON INT DATE 1997"      ---YCPS-2300
  C2400     = "R CURR IN ACTIVE MILITARY? 1997"         ---YCPS-2400
  C2600     = "R OR HH MEMBER OWN BUS OR FARM? 1997"    ---YCPS-2600
  C2800     = "WRK FOR PAY LAST WK? NT OWN FARM 1997"   ---YCPS-2800
  C2900     = "WRK FOR PAY LAST WK? (OWN FARM) 1997"    ---YCPS-2900
  C3100     = "ANY UNPAID WRK FAMILY BUS/FARM? 1997"    ---YCPS-3100
  C78001    = "R HAVE DIS PREVENT WRK? (DIS)L1 1997"    ---YCPS-78001
  C78002    = "R HAVE DIS PREVENT WRK? (DIS)L2 1997"    ---YCPS-78002
  C79001    = "R HAVE DIS PREVENT WRK? (UNAB)L1 1997"   ---YCPS-79001
  C79002    = "R HAVE DIS PREVENT WRK? (UNAB)L2 1997"   ---YCPS-79002
  C82001    = "ANY JOB LAST WK? NT OWN BUS/FARML1 1997" ---YCPS-82001
  C82002    = "ANY JOB LAST WK? NT OWN BUS/FARML2 1997" ---YCPS-82002
  C87001    = "ON LAYOFF LAST WK?L1 1997"               ---YCPS-87001
  C87002    = "ON LAYOFF LAST WK?L2 1997"               ---YCPS-87002
  C96001    = "R PAID FOR TIME OFF LAST WK?L1 1997"     ---YCPS-96001
  C96002    = "R PAID FOR TIME OFF LAST WK?L2 1997"     ---YCPS-96002
  C10400    = "ENT USUAL HRS/WK AT MAIN JOBL1 1997"     ---YCPS-10400
  C106001   = "ENT USUAL HRS/WK AT JOBL1 1997"          ---YCPS-106001
  C106002   = "ENT USUAL HRS/WK AT JOBL2 1997"          ---YCPS-106002
  C11000    = "ENT USUAL HRS/WK AT OTH JOBL1 1997"      ---YCPS-11000
  C14000    = "R WANT FULL-TIME WRK?L1 1997"            ---YCPS-14000
  C14100    = "RSN WRK PART-TIMEL1 1997"                ---YCPS-14100
  C14200    = "RSN NT WANT FULL-TIMEL1 1997"            ---YCPS-14200
  C15200    = "TTL HRS WRK MAIN JOB LAST WK (1)L1 1997" ---YCPS-15200
  C15300    = "TTL HRS WRK MAIN JOB LAST WK (2)L1 1997" ---YCPS-15300
  C15800    = "TTL HRS WRK OTH JOBS LAST WKL1 1997"     ---YCPS-15800
  C15900    = "TTL HRS WRK AT OTH JOB LAST WKL1 1997"   ---YCPS-15900
  C176001   = "COULD RTRN WRK LAST WK? (LAYOFF)L1 1997" ---YCPS-176001
  C176002   = "COULD RTRN WRK LAST WK? (LAYOFF)L2 1997" ---YCPS-176002
  C186001   = "TRY FIND WRK L 4 WKS? (1-4 MOS)L1 1997"  ---YCPS-186001
  C186002   = "TRY FIND WRK L 4 WKS? (1-4 MOS)L2 1997"  ---YCPS-186002
  C23600    = "COULD STR JOB LAST WK? (LAYOFF)L1 1997"  ---YCPS-23600
  C23700    = "RSN NOT STR JOB LAST WK (LAYOFF)L1 1997" ---YCPS-23700
  C27300    = "MAIN RSN NOT LOOK WRK LAST 4 WKS 1997"   ---YCPS-27300
  C30700    = "WHEN R LAST WRK AT A JOB? 1997"          ---YCPS-30700
  C30800    = "RS PRESENT SITUATION TO NOT WRK? 1997"   ---YCPS-30800


/*Initialize esr*/
esr=-1;
if C2100=-2 then esr=-2;
if C2100=-3 then esr=-3;
if C2100=0 or C2100=-4 then esr=-4;

/*Define some arrays to be used later in the program at various times */
array C7800 C78001 C78002;
array C7900 C79001 C79002;
array C8200 C82001 C82002;
array C8700 C87001 C87002;
array C9600 C96001 C96002;
array C10600 C106001 C106002;
array C17600 C176001 C176002;
array C18600 C186001 C186002;

/*Create hrck6 and hrck7 for when the hh owns a farm and when the hh does not own a farm*/
hrck6=3;
if (C15200=0 and C15900=0) and (C2800=0 or C2800=-2 or C2800=-1 or C2800=-3)
 then hrck6=1;
if (C15200=0 and C15900=0) then hrck6=2;

if (C10400 ge 0 and C11000 ge 0) then hruslt=C10400+C11000;
if (C10400 ge 0 and C11000 lt 0) then hruslt=C10400;
if (C11000 ge 0 and C10400 lt 0) then hruslt=C11000;

if (C15200 ge 0 and C15900 ge 0) then hractt=C15200+C15900;
if (C15200 ge 0 and C15900 lt 0) then hractt=C15200;
if (C15900 ge 0 and C15200 lt 0) then hractt=C15900;

hrck7=5;
if (C2900=0 or C2900=-2 or C2900=-1 or C2900=-3) and ((C15200 lt 15 and C15200 ge 0)
 or C15200 eq -2) then hrck7=1;
if (C2900=0 or C2900=-2 or C2900=-1 or C2900=-3) and (C15200 ge 15) then hrck7=2;
if (hruslt ge 35) and (hractt lt 35) and (C15200 ge 0) then hrck7=3;
if (hruslt ge 35) and (hractt lt 35) and (C15900 ge 0) then hrck7=3;
if (C14000=1 and hractt lt 35) and (C14100=1 or C14100=2 or C14100=3) then hrck7=4;


/*If hh owns a farm and worked last week or was absent from work:*/
if C2100=1 and C2600=1 then do;

	/* If at work:*/
do I=1 to 2;
	if (hrck7 eq 2 or hrck7 eq 3 or hrck7 eq 4 or hrck7 eq 5) then do;
		if C2900=1 or (C2900=0 and C3100=1 and C10600(I)>=15) then esr=1;
	end;
end;

	/* If absent:*/
do I=1 to 2;
	if (C2900=0 and C3100=0 and C8200(I)=1 and C9600(I)=1)
	or (C2900=0 and C3100=0 and C8200(I)=1 and C9600(I)=0 and C10600(I)>=15)
	 then esr=2;
 end;
end;

/*If hh does not own a farm and worked or was absent from work during last week*/
	/* If at work:*/
	if C2800=1 and hrck6 eq 3 and C2100=1 and C2600 le 1 then esr=1;

	/* If absent:*/
do I=1 to 2;
	if C2800=0 and C8200(I)=1 and C2100=1 and C2600 le 1 then esr=2;
end;

/*If laid off during last week*/
do I=1 to 2;
	if (C2100=1 and C8700(I)=1 and C17600(I)=1) then esr=3; 
end;
	
/*If unemployed and looking for a job during last week*/
do I=1 to 2;
	if (C2100=1 and C18600(I)=1 and C23600=1)
	or (C2100=1 and C18600(I)=1 and C23600=0 and C23700=1)
	then esr=4;
end;

/*If not in the labor force and retired */
if C2100=1 and (C2800=2 or C2900=3 or C30800=5) then esr=5;

/*If not in the labor force and disabled */
	/* If hh owns a farm:*/
do I=1 to 2;
	if C2100=1 and C2600=1 then do;
	if C2900=3 and (C7800(I)=1 or C7900(I)=1) then esr=6;
	end;
end;
	/* If hh does not own a farm:*/
do I=1 to 2;
	if C2100=1 and C2600=0 then do;
	if C2800=3 and (C7800(I)=1 or C7900(I)=1) then esr=6;
	end;
end;

if esr=-1 then do;

/*If not in the labor force and "other" category:*/
if C2100=1 and (C30700=3 or C30800=1 or C30800=2 or C30800=3 or C30800=4 or C30800=6)
 then esr=7;

/*If in the army during last week*/
if C2300=1 and C2400=1 then esr=8;

end;

/* Create the Collapsed ESR code */
if esr=1 or esr=2 then collesr=1;
if esr=3 or esr=4 then collesr=2;
if esr=5 or esr=6 or esr=7 then collesr=3;
if esr=8 then collesr=4;
if esr=-4 then collesr=-4;
if esr=-1 then collesr=-1;
if esr=-3 then collesr=-3;
if esr=-2 then collesr=-2;

endsas;